\START82\
\COMMENT=Program file dated 04/10/96, 18:39
\NAME=BTWNCURV
:ClrHome
:Menu("EXPS IN \Y1\+\Y2\?","YES",2,"NO",1)
:Lbl 1
:Disp "EXPRESSION OF","TOP CURVE"
:Input "IN QUOTES:",\Y1\
:Disp "EXPRESSION OF","BOTTOM CURVE"
:Input "IN QUOTES:",\Y2\
:Lbl 2
:FnOff 
:FnOn 1,2
:Input "LOWER BOUND:",A
:Input "UPPER BOUND:",B
:If A\>=\B
:Goto 2
:(B-A)/94\->\C
:A-C\->\Xmin
:B+C\->\Xmax
:4.7C\->\Xscl
:\Y2\(fMin(\Y2\,X,A,B))\->\D
:\Y1\(fMax(\Y1\,X,A,B))\->\E
:(E-D)/64\->\F
:D-8F\->\Ymin
:E+F\->\Ymax
:3.2F\->\Yscl
:A\->\G
:Lbl 3
:\Y1\(G)\->\H
:\Y2\(G)\->\I
:If H<I
:Then
:Disp "\Y1\ IS NOT","ALWAYS > \Y2\"
:Stop
:End
:G+4C\->\G
:If G\<=\B
:Goto 3
:Menu("DO YOU WANT...","AREA",4,"VOL CIRC REV",5,"CENTROID",8)
:Lbl 4
:fnInt(\Y1\-\Y2\,X,A,B)\->\G
:Shade(\Y2\,\Y1\,1,A,B)
:Text(57,0,"AREA=",G)
:Stop
:Lbl 5
:Menu("REVOLVE AROUND","HOR LINE Y=",6,"VERT LINE X=",7)
:Lbl 6
:Input "LINE: Y=?",H
:If H>D and H<E
:Then
:Disp "CANNOT BE","REVOLVED AROUND","THAT LINE"
:Stop
:End
:If H\>=\E
:H\->\E
:If H\<=\D
:H\->\D
:(E-D)/64\->\F
:D-8F\->\Ymin
:E+F\->\Ymax
:3.2F\->\Yscl
:abs (\pi\*fnInt((\Y1\-H)\^2\-(\Y2\-H)\^2\,X,A,B))\->\G
:Horizontal H
:Shade(\Y2\,\Y1\,1,A,B)
:Text(57,0,"VOL CIRC REV=",G)
:Stop
:Lbl 7
:Input "LINE: X=?",H
:If H>A and H<B
:Then
:Disp "CANNOT BE","REVOLVED AROUND","THIS LINE"
:Stop
:End
:A\->\Xmin
:B\->\Xmax
:If H\<=\A
:H\->\Xmin
:If H\>=\B
:H\->\Xmax
:(Xmax-Xmin)/94\->\C
:Xmin-C\->\Xmin
:Xmax+C\->\Xmax
:4.7C\->\Xscl
:2\pi\fnInt((abs (H-X))(\Y1\-\Y2\),X,A,B)\->\G
:Vertical H
:Shade(\Y2\,\Y1\,1,A,B)
:Text(57,0,"VOL CIRC REV=",G)
:Stop
:Lbl 8
:fnInt(\Y1\-\Y2\,X,A,B)\->\G
:fnInt(X(\Y1\-\Y2\),X,A,B)/G\->\H
:fnInt(((\Y1\+\Y2\)/2)(\Y1\-\Y2\),X,A,B)/G\->\I
:Shade(\Y2\,\Y1\,1,A,B)
:Pt-Change(H,I)
:Pt-Change(H+\Delta-x\,I)
:Pt-Change(H-\Delta-x\,I)
:Pt-Change(H,I+\Delta-y\)
:Pt-Change(H,I-\Delta-y\)
:Text(57,0,"X=",H)
:Text(57,49,"Y=",I)
:Stop
:COPYRIGHT STEPHEN OSTERMILLER APRIL 1996
\STOP82\