\START82\
\COMMENT=Program file dated 04/10/96, 18:39
\NAME=CURVE
:ClrHome
:Menu("EXP IN \Y1\?","YES",2,"NO",1)
:Lbl 1
:Disp "EXPRESSION"
:Input "IN QUOTES:",\Y1\
:Lbl 2
:FnOff 
:FnOn 1
:Input "LOWER BOUND:",A
:Input "UPPER BOUND:",B
:If A\>=\B
:Goto 2
:(B-A)/94\->\C
:A-C\->\Xmin
:B+C\->\Xmax
:4.7C\->\Xscl
:\Y1\(fMin(\Y1\,X,A,B))\->\D
:\Y1\(fMax(\Y1\,X,A,B))\->\E
:(E-D)/64\->\F
:D-8F\->\Ymin
:E+F\->\Ymax
:3.2F\->\Yscl
:Menu("DO YOU WANT","ARC LENGTH",3,"SURFACE OF REV",4)
:Lbl 3
:fnInt(\sqrt\(1+nDeriv(\Y1\,X,X)\^2\),X,A,B)\->\G
:Text(57,0,"ARC LENGTH=",G)
:Stop
:Lbl 4
:Menu("REVOLVE AROUND","HOR LINE Y=?",5,"VERT LINE X=?",6)
:Lbl 5
:Input "LINE: Y=",H
:If H>E and H<D
:Then
:Disp "CANNOT BE","REVOLVED AROUND","THIS LINE"
:Stop
:End
:If H\>=\E
:H\->\E
:If H\<=\D
:H\->\D
:(E-D)/64\->\F
:D-8F\->\Ymin
:E+F\->\Ymax
:3.2F\->\Yscl
:2\pi\(fnInt(abs (H-\Y1\)\sqrt\(1+nDeriv(\Y1\,X,X)\^2\),X,A,B)\->\G
:Horizontal H
:Text(57,0,"SURF AREA OF REV=",G
:Stop
:Lbl 6
:Input "LINE: X=",H
:If H>A and H<B
:Then
:Disp "CANNOT BE","REVOLVED AROUND","THIS LINE"
:Stop
:End
:A\->\Xmin
:B\->\Xmax
:If H\<=\A
:H\->\Xmin
:If H\>=\B
:H\->\Xmax
:(Xmax-Xmin)/94\->\C
:Xmin-C\->\Xmin
:Xmax+C\->\Xmax
:4.7C\->\Xscl
:2\pi\(fnInt(abs (H-X)\sqrt\(1+nDeriv(\Y1\,X,X)\^2\),X,A,B)\->\G
:If H<A
:Vertical A
:If H>B
:Vertical B
:Vertical H
:Text(57,0,"SURF AREA OF REV=",G
:Stop
:COPYRIGHT STEPHEN OSTERMILLER 1996
:
\STOP82\